子程序设计

例：设从 BUF 开始存放若干无符号字节数据，找出其中的最小值并以 16 进制形式输出。
子程序内包含有子程序的调用就是子程序嵌套没有什么特殊要求
ALdisp proc
push ax
push cx ; 实现 al 内容的显示
push ax ; 暂存 ax
mov cl,4
shr al,cl ; 转换 al 的高 4 位
call htoasc ; 子程序调用（嵌套）
pop ax ; 转换 al 的低 4 位
call htoasc ; 子程序调用（嵌套）
pop cx
pop ax
ret
ALdisp endp
例 : 嵌套子程序
; 将 AL 低 4 位表达的一位 16 进制数转换为 ASCII 码
HTOASC proc
push ax
push bx
push dx
mov bx,offset ASCII;BX 指向 ASCII 码表
and al,0fh ; 取得一位 16 进制数
xlat CS:ASCII
; 换码： AL ← CS:[BX ＋ AL] ，注意数据在代码段 CS
mov dl,al ; 显示
mov ah,2
int 21h
pop dx
pop bx
pop ax
ret ; 子程序返回
; 子程序的数据区
ASCII db 30h,31h,32h,33h,34h,35h,36h,37h
db 38h,39h,41h,42h,43h,44h,45h,46h
HTOASC endp
    这是一个具有局部变量的子程序。因为数据区与子程序都在代码段，所以利用了换码指令 XLAT 的另一种助记格式（写出指向缓冲区的变量名，目的是便于指明段超越前缀）。串操作 MOVS 、 LODS 和 CMPS 指令也可以这样使用，以便使用段超越前缀
    除采用段超越方法外，子程序与主程序的数据段不同时，我们还可以通过修改 DS 值实现数据存取；但需要保护和恢复 DS 寄存器
子程序的递归
当子程序直接或间接地嵌套调用自身时称为递归调用，含有递归调用的子程序称为递归子程序
递归子程序必须采用寄存器或堆栈传递参数，递归深度受堆栈空间的限制
例：求阶乘
N!= N*(N-1)! 当 N>0
1 当 N=0
.model small
.stack 256
.data
N dw 3
result dw ?
.code
.startup
mov bx,N
push bx ; 入口参数： N
call fact ; 调用递归子程序
pop result ; 出口参数： N ！
.exit 0
例 : 求自然数 N(N>=1) 的阶乘
; 计算 N! 的近过程
; 入口参数：压入 N ; 出口参数：弹出 N!
fact proc
push ax
push bp
mov bp,sp
mov ax,[bp+6] ; 取入口参数 N
cmp ax,0
jne fact1 ;N ＞ 0,N! ＝ N × (N-1)!
inc ax ;N ＝ 0,N! ＝ 1
jmp fact2
fact1: dec ax ;N-1
push ax
call fact ; 调用递归子程序求 (N-1)!
pop ax
mul word ptr [bp+6] ; 求 N × (N-1)!
fact2: mov [bp+6],ax ; 存入出口参数 N!
pop bp
pop ax
ret
fact endp
调用时进栈
返回时出栈
1
3!
2!
1!
子程序的重入
可重入子程序是指该子程序被某程序调用 , 但还未结束 , 又被另一个程序调用 , 这是在分时系统中 .
子程序的重入是指子程序被中断后又被中断服务程序所调用，能够重入的子程序称为可重入子程序。在子程序中，注意利用寄存器和堆栈传递参数和存放临时数据，而不要使用固定的存储单元（变量），就能够实现重入。
   子程序的重入不同于子程序的递归。重入是被动地进入，而递归是主动地进入；重入的调用间往往没有关系，而递归的调用间却是密切相关的。递归子程序也是可重入子程序。
ASCII 码转换为二进制数
① 首先判断输入为正或负数，并用一个寄存器记录
② 接着输入 0 ～ 9 数字（ ASCII 码），并减 30H 转换为二进制数
③ 然后将前面输入的数值乘 10 ，并与刚输入的数字相加得到新的数值
④ 重复②、③步，直到输入一个非数字字符结束
⑤ 负数进行求补，转换成补码；否则直接保存数值

本例采用 16 位寄存器表达数据，所以只能输入＋ 327677 ～－ 32768 间的数值
但该算法适合更大范围的数据
例题 :
例：从键盘输入有符号十进制数
子程序从键盘输入一个有符号十进制数；子程序还包含将 ASCII 码转换为二进制数的过程
输入时，负数用“－”引导，正数直接输入或用“＋”引导
子程序用寄存器传递出口参数，主程序调用该子程序输入 10 个数据
.data
count = 10
array dw count dup(0) ; 预留数据存储空间
.code
.startup
mov cx,count
mov bx,offset array
again: call read ; 调用子程序输入一个数据
mov [bx],ax ; 将出口参数存放缓冲区
inc bx
inc bx
call dpcrlf
; 调用子程序，光标回车换行以便输入下一个数据
loop again
.exit 0
; 输入有符号 10 进制数的通用子程序
; 出口参数： AX ＝补码表示的二进制数值
; 说明：负数用“－”引导，正数用“＋”引导或直接输入；数据范围是＋ 32767 ～－ 32768
read proc
push bx
push cx
push dx
xor bx,bx ;BX 保存结果
xor cx,cx
;CX 为正负标志， 0 为正，－ 1 为负
mov ah,1 ; 输入一个字符
int 21h
cmp al,'+' ; 是“＋”，继续输入字符
jz read1
cmp al,'-' ; 是“－”，设置－ 1 标志
jnz read2 ; 非“＋”和“－”，转 read2
mov cx,-1
read1: mov ah,1 ; 继续输入字符
int 21h
read2: cmp al,'0‘
; 不是 0 ～ 9 之间的字符，则输入数据结束
jb read3
cmp al,'9'
ja read3
sub al,30h
; 是 0 ～ 9 之间的字符，则转换为二进制数
; 利用移位指令，实现数值乘 10 ： BX ← BX × 10
shl bx,1
mov dx,bx
shl bx,1
shl bx,1
add bx,dx
;bx 内容乘 10
mov ah,0
add bx,ax
; 已输入数值乘 10 后，与新输入数值相加
jmp read1 ; 继续输入字符
read3: cmp cx,0
jz read4
neg bx ; 是负数，进行求补
   例：显示有符号十进制数
子程序在屏幕上显示一个有符号十进制数；子程序还包含将二进制数转换为 ASCII 码的过程
显示时，负数用“－”引导，正数直接输出、没有前导字符

子程序的入口参数用共享变量传递，主程序调用该子程序显示 10 个数据
.data
count = 10
array dw 1234,-1234,0,1,-1,32767
dw -32768,5678,-5678,9000
wtemp dw ? ; 共享变量
.code
.startup
mov cx,count
mov bx,offset array
again: mov ax,[bx]
mov wtemp,ax ; 将入口参数存入共享变量
call write ; 调用子程序显示一个数据
inc bx
inc bx
call dpcrlf ; 便于显示下一个数据
loop again
.exit 0
; 显示有符号 10 进制数的通用子程序
入口参数：共享变量 wtemp
write proc
push ax
push bx
push dx
mov ax,wtemp ; 取出显示数据
test ax,ax ; 判断零、正数或负数
jnz write1
mov dl,'0' ; 是零，显示“ 0 ” 后退出
mov ah,2
int 21h
jmp write5
write1: jns write2 ; 是负数，显示“－”
mov bx,ax ;AX 数据暂存于 BX
mov dl,'-'
mov ah,2
int 21h
mov ax,bx
neg ax ; 数据求补（求绝对值）
write2: mov bx,10
push bx
;10 压入堆栈，作为退出标志
write3: cmp ax,0 ; 数据（余数）为零
jz write4 ; 转向显示
sub dx,dx ; 扩展被除数 DX.AX
div bx ; 数据除以 10 ： DX.AX ÷ 10
add dl,30h
; 余数（ 0 ～ 9 ）转换为 ASCII 码
push dx
; 数据各位先低位后高位压入堆栈
jmp write3
write4: pop dx
; 数据各位先高位后低位弹出堆栈
cmp dl,10 ; 是结束标志 10 ，则退出
je write5
mov ah,2 ; 进行显示
int 21h
jmp write4
write5: pop dx
pop bx
pop ax
ret ; 子程序返回
write endp
; 使光标回车换行的子程序
dpcrlf proc
... ; 省略
dpcrlf endp
end